init

Telegram/ThirdParty/dispatch/tools/dispatch_timers.d

@@ -0,0 +1,89 @@
+#!/usr/sbin/dtrace -s
+
+/*
+ * Copyright (c) 2012-2013 Apple Inc. All rights reserved.
+ *
+ * @APPLE_APACHE_LICENSE_HEADER_START@
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * @APPLE_APACHE_LICENSE_HEADER_END@
+ */
+
+/*
+ * Usage: dispatch_timers.d -p [pid]
+ *        traced process must have been executed with
+ *        DYLD_LIBRARY_PATH=/usr/lib/system/introspection or with
+ *        DYLD_IMAGE_SUFFIX=_profile or DYLD_IMAGE_SUFFIX=_debug
+ */
+
+#pragma D option quiet
+#pragma D option zdefs
+
+typedef struct dispatch_trace_timer_params_s {
+	int64_t deadline, interval, leeway;
+} *dispatch_trace_timer_params_t;
+
+dispatch$target:libdispatch*.dylib::timer-configure,
+dispatch$target:libdispatch*.dylib::timer-program,
+dispatch$target:libdispatch*.dylib::timer-wake,
+dispatch$target:libdispatch*.dylib::timer-fire /!start/ {
+	start = walltimestamp;
+}
+
+/*
+ * Trace dispatch timer configuration and programming:
+ * Timer configuration indicates that dispatch_source_set_timer() was called.
+ * Timer programming indicates that the dispatch manager is about to sleep
+ * for 'deadline' ns (but may wake up earlier if non-timer events occur).
+ * Time parameters are in nanoseconds, a value of -1 means "forever".
+ *
+ * probe timer-configure/-program(dispatch_source_t source,
+ *         dispatch_function_t function, dispatch_trace_timer_params_t params)
+ */
+dispatch$target:libdispatch*.dylib::timer-configure,
+dispatch$target:libdispatch*.dylib::timer-program {
+	this->p = (dispatch_trace_timer_params_t)copyin(arg2,
+			sizeof(struct dispatch_trace_timer_params_s));
+	printf("%8dus %-15s: 0x%0?p deadline: %11dns interval: %11dns leeway: %11dns",
+			(walltimestamp-start)/1000, probename, arg0,
+			this->p ? this->p->deadline : 0, this->p ? this->p->interval : 0,
+			this->p ? this->p->leeway : 0);
+	usym(arg1);
+	printf("\n");
+}
+dispatch$target:libdispatch*.dylib::timer-configure {
+	printf("              / --- Begin ustack");
+	ustack();
+	printf("              \ --- End ustack\n");
+}
+
+/*
+ * Trace dispatch timer wakes and fires:
+ * Timer wakes indicate that the dispatch manager woke up due to expiry of the
+ * deadline for the specified timer.
+ * Timer fires indicate that that the dispatch manager scheduled the event
+ * handler of the specified timer for asynchronous execution (may occur without
+ * a corresponding timer wake if the manager was awake processing other events
+ * when the timer deadline expired).
+ *
+ * probe timer-wake/-fire(dispatch_source_t source,
+ *         dispatch_function_t function)
+ */
+dispatch$target:libdispatch*.dylib::timer-wake,
+dispatch$target:libdispatch*.dylib::timer-fire {
+	printf("%8dus %-15s: 0x%0?p%-70s", (walltimestamp-start)/1000, probename,
+			arg0, "");
+	usym(arg1);
+	printf("\n");
+}

Telegram/ThirdParty/dispatch/tools/dispatch_trace.d

@@ -0,0 +1,76 @@
+#!/usr/sbin/dtrace -s
+
+/*
+ * Copyright (c) 2010-2013 Apple Inc. All rights reserved.
+ *
+ * @APPLE_APACHE_LICENSE_HEADER_START@
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * @APPLE_APACHE_LICENSE_HEADER_END@
+ */
+
+/* 
+ * Usage: dispatch_trace.d -p [pid]
+ *        traced process must have been executed with
+ *        DYLD_LIBRARY_PATH=/usr/lib/system/introspection or with
+ *        DYLD_IMAGE_SUFFIX=_profile or DYLD_IMAGE_SUFFIX=_debug
+ */
+
+#pragma D option quiet
+#pragma D option zdefs
+#pragma D option bufsize=16m
+
+BEGIN {
+	printf("%-8s %-3s %-8s   %-35s%-15s%-?s   %-43s%-?s   %-14s%-?s    %s\n",
+		"Time us", "CPU", "Thread", "Function", "Probe", "Queue", "Label",
+		"Item", "Kind", "Context", "Symbol");
+}
+
+dispatch$target:libdispatch*.dylib::queue-push,
+dispatch$target:libdispatch*.dylib::queue-pop,
+dispatch$target:libdispatch*.dylib::callout-entry,
+dispatch$target:libdispatch*.dylib::callout-return /!start/ {
+	start = walltimestamp;
+}
+
+/*
+ * Trace queue push and pop operations:
+ *
+ * probe queue-push/-pop(dispatch_queue_t queue, const char *label,
+ *         dispatch_object_t item, const char *kind,
+ *         dispatch_function_t function, void *context)
+ */
+dispatch$target:libdispatch*.dylib::queue-push,
+dispatch$target:libdispatch*.dylib::queue-pop {
+	printf("%-8d %-3d 0x%08p %-35s%-15s0x%0?p %-43s0x%0?p %-14s0x%0?p",
+		(walltimestamp-start)/1000, cpu, tid, probefunc, probename, arg0,
+		copyinstr(arg1, 42), arg2, copyinstr(arg3, 13), arg5);
+	usym(arg4);
+	printf("\n");
+}
+
+/*
+ * Trace callouts to client functions:
+ *
+ * probe callout-entry/-return(dispatch_queue_t queue, const char *label,
+ *         dispatch_function_t function, void *context)
+ */
+dispatch$target:libdispatch*.dylib::callout-entry,
+dispatch$target:libdispatch*.dylib::callout-return {
+	printf("%-8d %-3d 0x%08p %-35s%-15s0x%0?p %-43s%-?s   %-14s0x%0?p",
+		(walltimestamp-start)/1000, cpu, tid, probefunc, probename, arg0,
+		copyinstr(arg1, 42), "", "", arg3);
+	usym(arg2);
+	printf("\n");
+}

Telegram/ThirdParty/dispatch/tools/voucher_trace.d

@@ -0,0 +1,78 @@
+#!/usr/sbin/dtrace -s
+
+/*
+ * Copyright (c) 2017 Apple Inc. All rights reserved.
+ *
+ * @APPLE_APACHE_LICENSE_HEADER_START@
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * @APPLE_APACHE_LICENSE_HEADER_END@
+ */
+
+/*
+ * Usage: voucher_trace.d -p [pid]
+ *        traced process must have been executed with
+ *        DYLD_LIBRARY_PATH=/usr/lib/system/introspection or with
+ *        DYLD_IMAGE_SUFFIX=_profile or DYLD_IMAGE_SUFFIX=_debug
+ */
+
+#pragma D option quiet
+#pragma D option zdefs
+#pragma D option bufsize=16m
+
+BEGIN {
+	printf("Starting to trace voucher operations...\n");
+}
+
+voucher$target:libdispatch*.dylib::create
+{
+	printf("ALLOC   voucher 0x%p, thread %#llx, ref 1, port %#x, aid %#llx", arg0, tid, arg1, arg2);
+	ustack(10);
+	printf("\n")
+}
+
+voucher$target:libdispatch*.dylib::dispose
+{
+	printf("FREE    voucher 0x%p, thread %#llx, ref 0", arg0, tid);
+	ustack(10);
+	printf("\n")
+}
+
+voucher$target:libdispatch*.dylib::retain
+{
+	printf("RETAIN  voucher 0x%p, thread %#llx, ref %d", arg0, tid, arg1);
+	ustack(10);
+	printf("\n")
+}
+
+voucher$target:libdispatch*.dylib::release
+{
+	printf("RELEASE voucher 0x%p, thread %#llx, ref %d", arg0, tid, arg1);
+	ustack(10);
+	printf("\n")
+}
+
+voucher$target:libdispatch*.dylib::adopt
+{
+	printf("ADOPT   voucher 0x%p, thread %#llx", arg0, tid);
+	ustack(10);
+	printf("\n")
+}
+
+voucher$target:libdispatch*.dylib::orphan
+{
+	printf("ORPHAN  voucher 0x%p, thread %#llx", arg0, tid);
+	ustack(10);
+	printf("\n")
+}