init

cmake/external/openssl/CMakeLists.txt

@@ -0,0 +1,24 @@
+# This file is part of Desktop App Toolkit,
+# a set of libraries for developing nice desktop applications.
+#
+# For license and copyright information please follow this link:
+# https://github.com/desktop-app/legal/blob/master/LEGAL
+
+add_library(external_openssl INTERFACE IMPORTED GLOBAL)
+add_library(desktop-app::external_openssl ALIAS external_openssl)
+
+if (WIN32)
+    set(openssl_lib_loc ${libs_loc}/openssl3/out)
+elseif (APPLE)
+    set(openssl_lib_loc ${libs_loc}/openssl3)
+endif()
+
+add_subdirectory(openssl_common)
+add_subdirectory(openssl_ssl)
+add_subdirectory(openssl_crypto)
+
+target_link_libraries(external_openssl
+INTERFACE
+    desktop-app::external_openssl_ssl
+    desktop-app::external_openssl_crypto
+)

cmake/external/openssl/openssl_common/CMakeLists.txt

@@ -0,0 +1,21 @@
+# This file is part of Desktop App Toolkit,
+# a set of libraries for developing nice desktop applications.
+#
+# For license and copyright information please follow this link:
+# https://github.com/desktop-app/legal/blob/master/LEGAL
+
+add_library(external_openssl_common INTERFACE IMPORTED GLOBAL)
+add_library(desktop-app::external_openssl_common ALIAS external_openssl_common)
+
+if (NOT DESKTOP_APP_USE_PACKAGED AND NOT LINUX)
+    target_include_directories(external_openssl_common SYSTEM
+    INTERFACE
+        ${libs_loc}/openssl3/include
+    )
+endif()
+
+# OpenSSL 3 deprecated AES_set_encrypt_key/decrypt_key/ige_encrypt/cbc_encrypt
+target_compile_options(external_openssl_common
+INTERFACE
+    $<IF:$<BOOL:${MSVC}>,/wd4996,-Wno-deprecated-declarations>
+)

cmake/external/openssl/openssl_crypto/CMakeLists.txt

@@ -0,0 +1,43 @@
+# This file is part of Desktop App Toolkit,
+# a set of libraries for developing nice desktop applications.
+#
+# For license and copyright information please follow this link:
+# https://github.com/desktop-app/legal/blob/master/LEGAL
+
+add_library(external_openssl_crypto INTERFACE IMPORTED GLOBAL)
+add_library(desktop-app::external_openssl_crypto ALIAS external_openssl_crypto)
+
+target_link_libraries(external_openssl_crypto
+INTERFACE
+    desktop-app::external_openssl_common
+)
+
+if (DESKTOP_APP_USE_PACKAGED)
+    find_package(OpenSSL REQUIRED)
+    target_link_libraries(external_openssl_crypto INTERFACE OpenSSL::Crypto)
+    return()
+endif()
+
+add_library(external_openssl_crypto_bundled STATIC IMPORTED GLOBAL)
+add_library(desktop-app::external_openssl_crypto_bundled ALIAS external_openssl_crypto_bundled)
+
+if (WIN32)
+    set_target_properties(external_openssl_crypto_bundled PROPERTIES
+        IMPORTED_LOCATION "${openssl_lib_loc}/libcrypto${CMAKE_STATIC_LIBRARY_SUFFIX}"
+        IMPORTED_LOCATION_DEBUG "${openssl_lib_loc}.dbg/libcrypto${CMAKE_STATIC_LIBRARY_SUFFIX}"
+    )
+elseif (APPLE)
+    set_target_properties(external_openssl_crypto_bundled PROPERTIES
+        IMPORTED_LOCATION "${openssl_lib_loc}/libcrypto${CMAKE_STATIC_LIBRARY_SUFFIX}"
+    )
+else()
+    find_library(DESKTOP_APP_CRYPTO_LIBRARIES libcrypto.a REQUIRED)
+    set_target_properties(external_openssl_crypto_bundled PROPERTIES
+        IMPORTED_LOCATION "${DESKTOP_APP_CRYPTO_LIBRARIES}"
+    )
+endif()
+
+target_link_libraries(external_openssl_crypto
+INTERFACE
+    desktop-app::external_openssl_crypto_bundled
+)

cmake/external/openssl/openssl_ssl/CMakeLists.txt

@@ -0,0 +1,43 @@
+# This file is part of Desktop App Toolkit,
+# a set of libraries for developing nice desktop applications.
+#
+# For license and copyright information please follow this link:
+# https://github.com/desktop-app/legal/blob/master/LEGAL
+
+add_library(external_openssl_ssl INTERFACE IMPORTED GLOBAL)
+add_library(desktop-app::external_openssl_ssl ALIAS external_openssl_ssl)
+
+target_link_libraries(external_openssl_ssl
+INTERFACE
+    desktop-app::external_openssl_common
+)
+
+if (DESKTOP_APP_USE_PACKAGED)
+    find_package(OpenSSL REQUIRED)
+    target_link_libraries(external_openssl_ssl INTERFACE OpenSSL::SSL)
+    return()
+endif()
+
+add_library(external_openssl_ssl_bundled STATIC IMPORTED GLOBAL)
+add_library(desktop-app::external_openssl_ssl_bundled ALIAS external_openssl_ssl_bundled)
+
+if (WIN32)
+    set_target_properties(external_openssl_ssl_bundled PROPERTIES
+        IMPORTED_LOCATION "${openssl_lib_loc}/libssl${CMAKE_STATIC_LIBRARY_SUFFIX}"
+        IMPORTED_LOCATION_DEBUG "${openssl_lib_loc}.dbg/libssl${CMAKE_STATIC_LIBRARY_SUFFIX}"
+    )
+elseif (APPLE)
+    set_target_properties(external_openssl_ssl_bundled PROPERTIES
+        IMPORTED_LOCATION "${openssl_lib_loc}/libssl${CMAKE_STATIC_LIBRARY_SUFFIX}"
+    )
+else()
+    find_library(DESKTOP_APP_SSL_LIBRARIES libssl.a REQUIRED)
+    set_target_properties(external_openssl_ssl_bundled PROPERTIES
+        IMPORTED_LOCATION "${DESKTOP_APP_SSL_LIBRARIES}"
+    )
+endif()
+
+target_link_libraries(external_openssl_ssl
+INTERFACE
+    desktop-app::external_openssl_ssl_bundled
+)